アニメーションオーバーライドできる新関数

セカンドライフアバターのデフォルトの歩いたり座ったりするアニメーションは、今までは基本的に上書きするのにハックが必要でした。タイマーをコンマ数秒単位で回して、アバターの状態を監視する方法です。しかしこれはシムへの負荷がかなり掛かるものでした。

そこで最近、負荷を抑えつつアニメーションを上書きできる新関数が追加されました。

llSetAnimationOverride

llSetAnimationOverride( string anim_state, string anim )

llSetAnimationOverrideは、アニメーションを上書きします。第１引数は「上書きする状態」、第２引数は上書きするアニメーションの名前です。例えば、歩く動作をしているとき座るアニメーションを再生したい場合は、次のようにします。

default
{
    touch_start(integer num)
    {
        // パーミッションを取得
        llRequestPermissions(llDetectedKey(0), PERMISSION_OVERRIDE_ANIMATIONS);
    }
    
    run_time_permissions(integer perm)
    {
        if(perm & PERMISSION_OVERRIDE_ANIMATIONS)
        {
            // 歩く動作のとき、座るアニメーションをさせる
            llSetAnimationOverride("Walking", "sit");
        }
    } 
}

上書きできる状態は、これだけあります。

• Crouching
• CrouchWalking
• Falling Down
• Flying
• FlyingSlow
• Hovering
• Hovering Down
• Hovering Up
• Jumping
• Landing
• PreJumping
• Running
• Sitting
• Sitting on Ground
• Standing
• Standing Up
• Striding
• Soft Landing
• Taking Off
• Turning Left
• Turning Right
• Walking

アニメーションは、基本的にはプリムに格納しておいて、その名前を第２引数で指定するのですが、組み込みアニメーションであれば、プリムになくても使用できます。上記のサンプルも組み込みアニメーションを使いました。

llGetAnimationOverride

llGetAnimationOverride( string anim_state )

llGetAnimationOverrideは、いま再生しているアニメーションの名前を取得できます。引数には、アニメーションの名前を取得したい状態を指定します。歩いているときは、普段は「walk」というアニメーションが再生されていますが、さっきのllSetAnimationOverrideのサンプルを実行したあとで以下のスクリプトを動かすと、「sit」と表示されます。

default
{
    touch_start(integer num)
    {
        // パーミッションを取得
        llRequestPermissions(llDetectedKey(0), PERMISSION_OVERRIDE_ANIMATIONS);
    }
    
    run_time_permissions(integer perm)
    {
        if(perm & PERMISSION_OVERRIDE_ANIMATIONS)
        {
            // 歩いているときに再生されているアニメーションの名前を取得
            llOwnerSay(llGetAnimationOverride("Walking"));
        }
    }
}

llResetAnimationOverride

llResetAnimationOverride( string anim_state )

現在指定されているアニメーションを、デフォルトのものにリセットします。引数にはアニメーションをリセットしたい状態を指定します。llSetAnimationOverrideのサンプルを実行したあとで、次のスクリプトを動かすと、歩くときのアニメーションが「walk」にもどります。

default
{
    touch_start(integer num)
    {
        // パーミッションを取得
        llRequestPermissions(llDetectedKey(0), PERMISSION_OVERRIDE_ANIMATIONS);
    }
    
    run_time_permissions(integer perm)
    {
        if(perm & PERMISSION_OVERRIDE_ANIMATIONS)
        {
            // 歩いているときに再生されているアニメーションをデフォルトにもどす
            llResetAnimationOverride("Walking");
        }
    }
}

なお、llResetAnimationOverrideだけ引数に「ALL」が指定でき、すべてのアニメーションをリセットすることができます。

自分で何かつくるときはもちろん、既存のアニメーションオーバーライドツールを使う時も、できれば新しい関数を使って負荷をへらしているかチェックしてみるといいかもしれませんね（￣∇ ￣ ）

透視投影変換を使ってロックオンできるHUDをつくる

ロックオンできるHUDといっても、よくわからないと思うので、まずは動画をみてください。

赤い箱は土地にRezされたオブジェクトで、青い四角はHUDです。赤い箱にタッチすると箱が自分の現在の位置をシャウトするようになってて、それをHUD側がListenして箱が表示されている座標へ移動するようになってます。3Dシューティングなんかで敵の位置へカーソルが移動してロックオン状態になったりしますが、まさにそんな感じのものをつくりました。

使用している技術は透視投影変換で、これは3D上の世界を2次元の画面へマッピングするための手法です。ただ、これを説明するのは、ものすごく大変というか自分も完全には理解してないので、とりあえず赤い箱の位置を渡せばHUDをロックオンする位置に移動させる関数をいきなりお見せします。

// 引数にターゲットオブジェクトの位置を渡すと、そこにHUDをロックオンさせます
lockOn(vector pos)
{
    // Field of View レンズの画角を算出（SLのデフォルトの視野角は60度）
    float fov = 1.0 / llTan(60.0 * 0.5 * PI / 180.0);
    
    // カメラの情報を取得（要パーミッション）
    vector cameraPos = llGetCameraPos();
    rotation cameraRot = llGetCameraRot();
    
    // カメラとオブジェクトの距離を算出
    float dist = llVecDist(pos, cameraPos);
    
    // カメラとオブジェクト間をベクトルで表現
    vector objVec = pos - cameraPos;
    
    // カメラの回転を、X、Y、Zの各ベクトル表現に分解
    vector xVec = <1.0, 0.0, 0.0> * cameraRot;
    vector yVec = <0.0, 1.0, 0.0> * cameraRot;
    vector zVec = <0.0, 0.0, 1.0> * cameraRot;
    
    // オブジェクトへのベクトルとカメラの向いてる方向との角度差を得る
    rotation xRot = llRotBetween(objVec, xVec);
    rotation yRot = llRotBetween(objVec, yVec);
    rotation zRot = llRotBetween(objVec, zVec);
    
    // オブジェクトへの距離をカメラを軸としたX、Y、Z方向の距離に分解
    float xDist = dist * llCos(llRot2Angle(xRot));
    float yDist = dist * llCos(llRot2Angle(yRot));
    float zDist = dist * llCos(llRot2Angle(zRot));
    
    // 距離と視野角から、HUDの位置を算出する
    float posY = yDist / xDist * fov / 2.0;
    float posZ = zDist / xDist * fov / 2.0;
    vector pos = <0.0, posY, posZ>;
    
    // HUDを移動させる
    llSetPrimitiveParams([PRIM_POSITION, pos]);
}

ゲームプログラミングとかしてる人じゃないと分かりませんよね。3Dの世界を2次元にマッピングする場合、遠くにあるものほど真ん中へ寄せて表示しないとそれらしくならないので、そういう処理をしてると思ってください。

図にするとこんな感じかな。

この技術はカソウセカイカメラでも使われています。まあちょっとしたバグがあって、コメントは正確な位置から少しズレるんですが・・・。コメントを空間に表示するとき位置をどう決めればいいのかわからなくて、試行錯誤しててこの方法にたどりついた感じです。

応用範囲は広くて、3Dシューティングゲームを作ったりできますし、なにかモノを指し示すガイドとしても使えるとおもいます。特に後者は、情報が整理されておらずカオスな仮想世界で何か探してもらうときに、かなり役に立つんじゃないでしょうか。

最後に実際に動作確認したスクリプトを載せておきます（￣∇ ￣ ）

赤い箱のスクリプト

// チャット用のチャンネル（適当）
integer CHANNEL = -84527;

default
{
    touch_start(integer total_number)
    {
        // 今の位置をシャウト
        llShout(CHANNEL, (string)llGetPos());
    }
}

青い四角のスクリプト

// Secondlifeのデフォルトの視野角
float ANGLE = 60.0;

// チャット用のチャンネル（適当）
integer CHANNEL = -84527;

// 引数にターゲットオブジェクトの位置を渡すと、そこにHUDをロックオンさせます
lockOn(vector pos)
{
    // Field of View レンズの画角を算出
    float fov = 1.0 / llTan(ANGLE * 0.5 * PI / 180.0);
    
    // カメラの情報を取得
    vector cameraPos = llGetCameraPos();
    rotation cameraRot = llGetCameraRot();
    
    // カメラのとオブジェクトの距離を算出
    float dist = llVecDist(pos, cameraPos);
    
    // カメラとオブジェクト間をベクトルで表現
    vector objVec = pos - cameraPos;
    
    // カメラの回転を、X、Y、Zの各ベクトル表現に分解
    vector xVec = <1.0, 0.0, 0.0> * cameraRot;
    vector yVec = <0.0, 1.0, 0.0> * cameraRot;
    vector zVec = <0.0, 0.0, 1.0> * cameraRot;
    
    // オブジェクトへのベクトルとカメラの向いてる方向との角度差を得る
    rotation xRot = llRotBetween(objVec, xVec);
    rotation yRot = llRotBetween(objVec, yVec);
    rotation zRot = llRotBetween(objVec, zVec);
    
    // オブジェクトへの距離をカメラを軸としたX、Y、Z方向の距離に分解
    float xDist = dist * llCos(llRot2Angle(xRot));
    float yDist = dist * llCos(llRot2Angle(yRot));
    float zDist = dist * llCos(llRot2Angle(zRot));
    
    // 距離と視野角から、HUDの位置を算出する
    float posY = yDist / xDist * fov / 2.0;
    float posZ = zDist / xDist * fov / 2.0;
    vector pos = <0.0, posY, posZ>;
    
    // HUDを移動させる
    llSetPrimitiveParams([PRIM_POSITION, pos]);
}


default
{
    state_entry()
    {
        // ターゲットオブジェクトの発信する位置情報をListen
        llListen(CHANNEL, "", NULL_KEY, "");
        
        // HUDとしてアタッチされてる場合のみ、カメラのパーミッションを取得
        if(llGetAttached() >= ATTACH_HUD_CENTER_2 && llGetAttached() <= ATTACH_HUD_BOTTOM_RIGHT) 
        {
            llRequestPermissions(llGetOwner(), PERMISSION_TRACK_CAMERA);
        }
    }
    
    on_rez(integer start_param) 
    {
        llResetScript();
    }
    
    listen(integer channel, string name, key id, string message)
    {
        // サンプルなのでチェックはなしです

        // Lock on 
        lockOn((vector)message);
    }
    
    run_time_permissions(integer perm) {
        if(perm & PERMISSION_TRACK_CAMERA) {
            // do nothing
        }
    }
    
}

LSLスクリプトでJSONを扱う（一括変換編）

この記事は、セカンドライフ 技術系 Advent Calendar 2013向けに書かれた記事です。今回は、JSONとリストを一括変換するLSL関数を紹介します。

llJson2List

list llJson2List(string src)

JSON文字列を、LSLのリスト変数に変換します。引数に対象のJSONを指定し、返り値が変換したリストになります。

// リストの表示をわかりやすくするため、文字列への変換関数を用意しておきます
string dump(list l)
{
    return "[ " + llDumpList2String(l, ",") + " ]";
}


// JSONオブジェクトを変換してみます
list value1 = llJson2List("{ \"a\" : 1, \"b\" : true }");

// [ a,1,b,﷖ ]と表示されます。strided list（ひとつ飛ばしのリスト）になります
// リストの最後の項は、JSON_TRUEです
llOwnerSay(dump(value1));

// JSON配列を変換してみます
list value2 = llJson2List("[ 1, \"two\", \"3\" ]");

// [ 1,two,3 ]と表示されます。普通にリストに変換されます
// ちなみにリストの要素は全て文字列型になります
llOwnerSay(dump(value2));

// 単一の値を変換してみます
list value3 = llJson2List("1");

// [ 1 ]と表示されます。ひとつだけ要素を含んだリストになります
llOwnerSay(dump(value3));

// keyをnullにした不正なJSONを変換してみます
list value4 = llJson2List("{ \"a\" : 1, null : true }");

// [ ﷐ ]と表示されます。JSON_INVALIDだけ含んだリストです
llOwnerSay(dump(value4));

JSONオブジェクトは、strided list（ひとつ飛ばしのリスト）に変換されます。LSLにはstrided listを扱える関数がいくつかあるので活用できそうです。また、JSONをリストに変換した時、リストの要素は全て文字列型になります。これは例えば数値をfloatに勝手に変換して桁落ちしたりしないような配慮だとおもいます。

不正なJSONが入力された場合は、JSON_INVALIDのみ含んだリストが返されるので、入力値のJSONが信頼できない場合は、条件分岐でJSON_INVALIDと比較するのが良さそうです。

if(llList2String(value4, 0) != JSON_INVALID)
{
    // 本来の処理
    // ...
}

では、ネストしたJSONは正しく変換できるのでしょうか。

string json = "
{
    \"a\" : 1,
    \"b\" : [ 1, \"two\", \"3\" ],
    \"c\" : { \"d\" : 2, \"e\" : false }
}";

// ネストしたJSONを変換してみます
list value1 = llJson2List(json);

// [ a,1,b,[ 1, "two", "3" ],c,{ "d" : 2, "e" : false } ]と表示されます。
llOwnerSay(dump(value1));

JSONの内部にあるJSONは再帰的に変換されず、文字列としてリスト内に格納されます。なので、深いところにある値を取得するには、自力で何回か変換してやる必要があります。

// [ 1, \"two\", \"3\" ]の部分を取得し、変換します
list value2 = llJson2List(llList2String(value1, 3));

// [ 1,two,3 ]と表示されます。
llOwnerSay(dump(value2));

// { \"d\" : 2, \"e\" : false }の部分を取得し、変換します
list value3 = llJson2List(llList2String(value1, 5));

// [ d,2,e,﷗ ]と表示されます。最後の項はJSON_FALSEです
llOwnerSay(dump(value3));

llList2Json

string llList2Json(string type, list values)

LSLのリストを、JSON文字列に変換します。引数の１つめはJSONの種類（JSON_OBJECTか、JSON_ARRAY）、２つめは変換するリストです。返り値は変換したJSON文字列になります。

// JSONオブジェクトに変換してみます
string value1 = llList2Json(JSON_OBJECT, ["a", 1, "b", JSON_TRUE]);

// {"a":1,"b":true}と表示されます。JSON_TRUEはtrueに変換されます
llOwnerSay(value1);

// JSON配列に変換してみます
string value2 = llList2Json(JSON_ARRAY, [1, "two", "3"]);

// [1,"two","3"]と表示されます。ListからJSONへの変換では数値と文字列は区別されます
llOwnerSay(value2);

ちなみに、keyに数値を指定するなど、おかしな操作をするとJSON_INVALIDが返ります

// Keyに1を指定
string value3 = llList2Json(JSON_OBJECT, [1, 2]);

// JSONのKeyは文字列でないといけません
if(value3 == JSON_INVALID)
{
    llOwnerSay("不正な操作です");
}

では、ネストしたJSONを作ってみましょう。

/*
こんなJsonを作ってみます
{
    "a" : 1,
    "b" : [ 1, "two", "3" ],
    "c" : { "d" : 2, "e" : false }
}
*/

// 内部のJSON（配列）を、先に作っておきます
string subjson1 = llList2Json(JSON_ARRAY, [1, "two", "3"]);

// 内部のJSON（オブジェクト）を、先に作っておきます
string subjson2 = llList2Json(JSON_OBJECT, ["d", 2, "e", JSON_FALSE]);

// 最後にそれらを合成します
string json = llList2Json(JSON_OBJECT, ["a", 1, "b", subjson1, "c", subjson2]);

// {"a":1,"b":[1,"two","3"],"c":{"d":2,"e":false}}と表示されます
llOwnerSay(json);

小さい部品から先に作っていけばいいわけですね。ちなみにこういう書き方もできます。

// 一気に組みあげます
string json = llList2Json(JSON_OBJECT,
    [
     "a", 1,
     "b", llList2Json(JSON_ARRAY, [1, "two", "3"]),
     "c", llList2Json(JSON_OBJECT, ["d", 2, "e", JSON_FALSE])
    ]
);

// {"a":1,"b":[1,"two","3"],"c":{"d":2,"e":false}}と表示されます
llOwnerSay(json);

以上で、一括変換の説明も終わりです。

2回に渡ってLSLでJSONを扱う方法を書いてきました。JSONを扱えるようになることで、Webサービスとの連携がやりやすくなるはずです。例えばTwitterもJSONを返すAPIがありますね（OpenAuthの認証が必要ですが）。しかし一方でなんでもJSONオブジェクトにしちゃったりすると、Keyの分だけ少ないLSLメモリを消費してしまうという罠もあります。本番運用では、そのへんも見極めて最適なデータ形式を選択していけるといいんじゃないかなとおもいます（￣∇ ￣ ）

LSLスクリプトでJSONを扱う（単要素処理編）

これは、セカンドライフ 技術系 Advent Calendar 2013向けに書かれた記事です。LSLにJSONを扱う関数が追加されたので、今回はそれを紹介します。

JSONとは

JSONはJavascriptの記法で書かれたデータなのですが、いろんなプログラミング言語にJSONを扱うためのライブラリがあるので、さまざまなプログラム間でデータをやりとりするときに使われています。

こんなかんじでオブジェクトと配列の組み合わせでJSONは構成されます。

// JSONオブジェクト
{ "a" : 1, "b" : true } 

// JSON配列
[ "c", 3, false ]

// 組み合わせ
[ "c", 3, false, { "a" : 1, "b" : true } ] 

LSLには「値を１つずつ処理する方法」「JSONをリストに一括で変換する方法」の、２通りのやり方が用意されています。一気に紹介しようと思ったのですが、意外と長くなってしまったので、今回は値を１つずつ処理する方法を紹介します。

llJsonGetValue

string llJsonGetValue(string json, list specifiers)

JSONから指定したパスにある値を文字列として取得します。第一引数に対象のJSONを指定して、第二引数のListでパスを指定します。

// JSONをリテラルで書く場合、ダブルクォーテーションはエスケープが必要です
string value1 = llJsonGetValue("{ \"a\" : 1, \"b\" : true }", ["a"]);

// 1と表示されます
llOwnerSay(value1);

// ネストした例、配列の４番目（０から始まるので）のオブジェクトの、bをKeyにもつ値を取得
string value2 = llJsonGetValue("[ \"c\", 3, false, { \"a\" : 1, \"b\" : true } ]", [3, "b"]);

// TRUEと表示してほしいところですが、﷖と表示されます
llOwnerSay(value2);

２つめの例をみるとわかるように、リストにパスとなる値を書いていくことで深い位置にある値もとってくることができます。しかし、うまくTRUEと表示されてくれません。LSLには定数として「TRUE」が用意されてるんですが、これって単に数値の１の置き換えでしかないので、実は真の意味で真偽値を表す定数ってないんですね。そこで、JSONの真偽値を表すために「JSON_TRUE」「JSON_FALSE」が追加されています。

// trueを取得します
string value1 = llJsonGetValue("{ \"a\" : 1, \"b\" : true }", ["b"]);

// このように、条件分岐を使うと人にもわかるように表示できます
if(value1 == JSON_TRUE)
{
    llOwnerSay("TRUEを取得しました");
}

定数は他にもあります。

// nullを取得します
string value1 = llJsonGetValue("{ \"a\" : 1, \"b\" : null }", ["b"]);

// nullは、JSON＿NULLであらわします
if(value1 == JSON_NULL)
{
    llOwnerSay("NULLを取得しました");
}

// 存在しないKeyを指定します
string value2 = llJsonGetValue("{ \"a\" : 1, \"b\" : null }", ["c"]);

// JSON_INVALIDが返ります
if(value2 == JSON_INVALID)
{
    llOwnerSay("不正な操作です");
}

llJsonSetValue

string llJsonSetValue(string json, list specifiers, string value)

当然値をセットする関数もあります。第一引数に対象のJSONを指定して、第二引数のListでパスを指定、第三引数でセットする値を指定します。返り値は値が更新されたJSONです。

// aをKeyとする値に数値の２をセットしています
string value1 = llJsonSetValue("{ \"a\" : 1, \"b\" : true }", ["a"], "2");

// {"a":2,"b":true}と表示されます
llOwnerSay(value1);

// ネストした例、今度は文字列の２をセットしています
string value2 = llJsonSetValue("[ \"c\", 3, false, { \"a\" : 1, \"b\" : true } ]", [3, "a"], "\"2\"");

// ["c",3,false,{"a":"2","b":true}]と表示されます。「数値」と「数字の文字列」は区別されています
llOwnerSay(value2);

// aをKeyとする値にオブジェクトをセットしています
string value3 = llJsonSetValue("{ \"a\" : 1, \"b\" : true }", ["a"], "{\"c\":1,\"d\":2}");

// {"a":{"c":1,"d":2},"b":true}と表示されます
llOwnerSay(value3);

// 存在しないKeyを指定すると、キーと値のペアを追加できます
string value4 = llJsonSetValue("{ \"a\" : 1, \"b\" : true }", ["c"], "3");

// {"a":1,"b":true,"c":3}と表示されます
llOwnerSay(value4);

数値と数字の文字列が区別されたり、オブジェクトをセットできたり、けっこう自由度が高いです。また特殊な定数を使った便利な操作も用意されています。

// JSON_NULLを使って、nullをセットしています
string value1 = llJsonSetValue("{ \"a\" : 1, \"b\" : true }", ["a"], JSON_NULL);

// {"a":null,"b":true}と表示されます
llOwnerSay(value1);

// JSON_APPEND定数を使って、配列の最後に値を追加しています。要素数がわからないとき便利です
string value2 = llJsonSetValue("[ \"c\", 3, false, { \"a\" : 1, \"b\" : true } ]", [JSON_APPEND], "5");

// ["c",3,false,{ "a" : 1, "b" : true },5]と表示されます
llOwnerSay(value2);

// ネストした配列でも可能です
string value3 = llJsonSetValue("[ \"c\", 3, false, [ \"a\", \"b\"] ]", [3, JSON_APPEND], "6");

// ["c",3,false,["a","b",6]]と表示されます
llOwnerSay(value3);

// JSON_DELETE定数を使って、値を削除しています
string value4 = llJsonSetValue("{ \"a\" : 1, \"b\" : true }", ["a"], JSON_DELETE);

// {"b":true}と表示されます
llOwnerSay(value4);

// 配列でも削除できます
string value5 = llJsonSetValue("[ \"a\", \"b\"}", [0], JSON_DELETE);

// ["b"]と表示されます
llOwnerSay(value5);

llJsonValueType

string llJsonValueType(string json, list specifiers)

指定したパスにある値のタイプを取得します。第一引数に対象のJSONを指定して、第二引数のListでパスを指定します。返り値は、以下の定数のどれかです。

• JSON_INVALID
• JSON_OBJECT
• JSON_ARRAY
• JSON_NUMBER
• JSON_STRING
• JSON_NULL
• JSON_TRUE
• JSON_FALSE

string json = "[ \"c\", 3, false, { \"a\" : null, \"b\" : true } ]";

// JSON_STRING
string type1 = llJsonValueType(json, [0]);
if(type1 == JSON_STRING) llOwnerSay("string");

// JSON_NUMBER
string type2 = llJsonValueType(json, [1]);
if(type2 == JSON_NUMBER) llOwnerSay("number");

// JSON_TRUE
string type3 = llJsonValueType(json, [3, "b"]);
if(type3 == JSON_TRUE) llOwnerSay("true");

// JSON_NULL
string type4 = llJsonValueType(json, [3, "a"]);
if(type4 == JSON_NULL) llOwnerSay("null");

// JSON_OBJECT
string type5 = llJsonValueType(json, [3]);
if(type5 == JSON_OBJECT) llOwnerSay("object");

// JSON_INVALID
string type6 = llJsonValueType(json, [9]);
if(type6 == JSON_INVALID) llOwnerSay("invalid");

以上で、単要素処理編はおしまいです。しかしJSONのパスをリストで表すというのが、なんか斬新でした。次回、一括変換編は万一アドベントカレンダーが完走しなかった場合に書こうとおもいます。ま、まあきっと完走するよね・・・。

LSLの文法「型」

この記事は、セカンドライフ 技術系 Advent Calendarの、10日めの記事です。

いま、消えそうな言語ナンバーワン、LSLの文法について書いていきます。今日のお題は型です。

LSLは、次の型があります。

• integer（整数型）
• float（浮動小数点型）
• string（文字列型）
• key（識別子型）
• list （リスト型）
• vector（ベクトル型）
• rotation（回転型）

オブジェクト等の固有IDを表す「key型」、オブジェクトの大きさ・速度などを表す「vector型」、回転を表す「rotation型」等が、基本型に含まれてるのが特徴です。

integer型

−2,147,483,648 〜 +2,147,483,647の範囲をあらわす、4バイト整数です。

float型

1.175494351E-38 〜 3.402823466E+38の範囲をあらわす、浮動小数点数です。

string型

ごくごく一般的な文字列型です。「+」記号で連結します。

例：string value = "abc" + "def";

key型

セカンドライフのオブジェクトの識別子などに使われる型。ぶっちゃけUUIDです。

例：key value = "00000000-0000-0000-0000-000000000000";

list型

いわゆるリストです。要素に複数の型を混在させることができます。リストの入れ子はできません。ちなみに、LSLには配列はありません。

例：list value = [ 6, 1.8, "string" ];

vector型

float型３つからなる型。3D空間を扱うLSLでは何気に便利な型です。オブジェクトの位置、大きさ、速度なんかを表すのにつかいます。

例：vector value = <1.0, 2.0, 3.0>;

rotation型

回転型です。LSLの回転は4つの数字からなるクォータニオンで表します。クォータニオンはちょっとややこしい概念ですが、この形式にすることで回転の合成などが簡単になります。

例：rotation value = <0.0, 0.0, PI, 1.0>;

まとめ

全体的に、3Dを扱うのに特化した型になってるのがわかるとおもいます。ぼくは経験ないですが、ゲームプログラミングなどをしてると理解しやすいのかもしれません。

セカンドライフ、LSLスクリプトでできること

今年は、層の薄いセカンドライフのクリエイターが集まって、アドベントカレンダーに挑戦することになりました。これは、その1日目の記事になります。

セカンドライフ 技術系 Advent Calendar

初日だしHelloWorld的なプログラムをつくろうかと思ったんですが、そもそも文法の前にLSLはどんなことができるのか知っておいてもらったほうが、プログラムの説明も簡単になる気がしたので、今回はLSLでできることをパーッとあげてみることにします。

チャット、通信

セカンドライフでは、アバター同士がチャットで会話できますが、オブジェクトにチャットさせることもできます。「○○さんが入店しました〜」みたいな通知に使ったり、自分の作品をプリムに説明させたり、応用次第でいろいろ使えます。

また、アバター会話用以外のチャンネルをつかえば、裏でオブジェクト同士でメッセージを交換させるみたいな、イベントドリブン的な制御にも使うことができます。

プリム、オブジェクト操作

セカンドライフのものつくりはプリムが基本になります。プリムは立方体、円柱みたいな原始的な立体で、それを複数組み合わせてオブジェクトをつくります。

LSLでは、これらを動かしたり、色やテクスチャを変えたり、大きさを変えたり、パーティクルを放出させたり、いろんな操作をおこなえます。LSLスクリプトの効果を見た目で実感しやすいので、とりあえずLSLを試してみたい時にオススメです。

アバター操作

アバターを踊らせたり、装飾品を装着させたりできます。これも、見た目で実感しやすく試してみたい時にオススメです。

カメラ操作

カメラ、つまりクライアントビューワの視点を制御できます。なかなか使いドコロがむずかしいですが、仮想世界の映像をそのままムービーにする「マシネマ」なんかでは、かなり活用されています。

FPSゲーム向けにマウスルックモードに移行することもできます。

メディア制御

昔はセカンドライフ上のメディアは貧弱でしたが、最近はプリムの表面に、ムービーを流したり、HTMLを表示したりといったこともできるようになりました。映画館をつくるみたいな当たり前の用途から、セカンドライフと連携するWebサービスをつくって、そのHTMLをプリムに表示みたいな応用まで、かなり面白い使い方をされています。

検出（タッチ、衝突、センサー）

LSLは、プリムがアバターにタッチ（クリック）されたり、衝突されたりしたのを検出できます。これを使えば、ボタンにタッチした人にダイアログを表示するとか、衝突してきた人を吹き飛ばすみたいなことが可能です。

また、センサー機能で近くにいるアバター群を検出することもできます。

持ち物関連

各アバターは持ち物を持っています。LSLで特定のユーザにアイテムを送ったりすることが可能です。

また、アバターだけでなくプリムもアイテムを持つことができます。たとえば宝箱の形をしたオブジェクトに、金貨を入れておくみたいな感じで使えます。LSLでプリムの中のアイテムを消したり、他のプリムにアイテムを渡したりなど、いろんな操作がおこなえます。

土地の管理

セカンドライフの重要な概念として、土地があります。LSLで土地の起伏を調整したり、土地のプリム数をカウントしたり、いろんな管理ができます。

また、LSLから特定のユーザをBANしたりすることも可能です。

乗り物

物理関連の関数を使うだけでも乗り物はつくれるのですが、LSLには専用の関数があります。車だけでなく、ボート、飛行機、気球など様々なタイプの乗り物がつくれます。

HTTP通信

LSLは、HTTP通信の機能も備えています。HTMLを取得して、文字列操作で欲しい情報を抜き出したり、直接WebAPIを叩いたりなど、いろんな使い道があります。最近では、独自のWebサービスをつくって、プリムと連携させるような高度なやり方も増えてきました。

また、HTTPリクエストをだすだけでなく、HTTPリクエストを受け取ることもできます。プリムがWebサーバになってしまうわけですね。プリム間でHTTPリクエストを送り合って自律的に動作させたりすることも可能で応用範囲は広いです。

まとめ

セカンドライフはネット上にほとんど情報がでてなくて、なにができるのかそもそも分からない人が多いとおもいます。上記にあげたのは、まだ一部分で細かくみてけば、他にも色々できることはあります。へー、こんなことができるんだと少しでも興味を持っていただけたら幸いです。

現役セカンドライファーが見ている世界、昨今の言説をみて思うこと

ネットで話題になるのは「セカンドライフの中は、まだこんなにひどかった」みたいなブログ記事ばかりで、いささか残念なんですが、あれはネタでやってる面もあるので、細かいツッコミを入れても仕方ない気もします。

むしろ、昔セカンドライフの悪い点をあげた記事に、顔を真っ赤にして反論してしまってるのが、かえって印象を悪くしてたような気がします。

だから、いちいち挙げられた点に反論するより、なぜぼくがいつまでもセカンドライフをやっているのか、どこに可能性を感じているのか書いてみたほうがいい気がしてきました。

１，Yahoo、Googleになれるチャンス

今、ネットで「オレはYahoo、Google級のサービスを作ってやる」とか言ってる人は現実を見たほうがいいです。ネットは初期に成功した企業が大きな力をつけて業界はもう固まってしまいました。大きいプラットフォームをつくろうと思っても、もはや不可能なので、「ニッチをねらう」ことが、ネットサービスのセオリーにすらなっています。

逆に仮想世界は、それ自体がなくなってしまう可能性もありますが、Google級のサービスをつくれる可能性もたしかにあります。自分で未踏の地を切り開くのは大変ですが、力のある人なら、これほどやりがいがあることもないと思います。

この可能性の大きさが仮想世界の魅力です。

２，コンテンツは仮想世界でしか売れなくなる

こちらは、ちょっと具体的なこと。ぼくが仮想世界で描いてるビジョンの中でも、とりわけ大きな話です。笑う人もいるかもしれないですが、まじめに考えてます。

いま、コピーフリーなネットがコンテンツ産業を破壊する問題は、いよいよ切羽詰まったところにきています。どんなにコンテンツを作ってもコピーが容易になったため、新たなビジネスモデルを考えなければいけないと、みんな言っています。しかし、結局出てくるモデルは「コンテンツを囲い込んで課金する」という、技術の進歩によってできるようになったことをあえて制限するような、退行したものばかりです。

「できることをあえて制限する」「今までできてたことをできなくする」そんな後ろ向きな解決を選びつつあるのが現状ですが、ぼくは、まったく新しいビジネスモデルを作って前向きに解決することができると考えています。そしてそのカギは仮想世界にあります。

ちょっと考えてみてください。コンテンツを売る前向きな解決策として、「ライブで収益をあげる」という考え方があります。ライブの体験はコピーできません。グッズを売るのももちろんそうですが、家でいつでもコンテンツを消費するのとは違った、そのときしかできない体験にお金を払ってもらうわけです。

ぼくは、これはすばらしい解決策だと思います。しかし、残念ながらこのモデルが成り立つのは東京だけなのです。よほどの大手でないかぎり、ライブは東京でしか行われないので、地方の住民は移動コストというハンデがあるのです。では、この移動コストがなくなったらどうでしょうか？

仮想世界でヴァーチャルライブを行い、自宅の部屋から参加する

これが、コンテンツ問題を前向きに解決できる、唯一の解だとぼくは考えています。そして、これを実現するには色々やらないといけないことがあります。

• HMD、脳波コントローラ、ヘッドセットなど没入型インターフェースの普及
• 仮想世界の安定性の向上
• 日本的デザインをもっと作りやすく（メッシュインポートでかなり改善された）
• 表情連動などの機能追加

まだまだハードルは高いですが、ヴァーチャルライブの台頭は、仮想世界の勃興だけでなく、コンテンツ問題の解決にもつながり、いつかはこの流れがくると思っています。

リアルな人間じゃなくアバターでいいのかという人もいると思いますが、もともとアイドルなんかは偶像なわけでアバターのほうが都合がいい面もあります。またリアルの生々しさがないぶん、3Dエフェクトみたいな仮想世界でしかできない演出というのもあります。

好きな音楽をデータでなく仮想世界上の生の歌手から聞く。尊敬してるイラストレータの絵をみるだけでなく仮想世界上で自分の似顔絵を描いてもらう。未来の有料コンテンツはすべてライブ化します。なかでも、「声優のボイスチャット＋キャラクターのアバター」で行うライブはキラーコンテンツになるでしょう。

未来をみてほしい

今回ぼくが書いた話は荒唐無稽に聞こえるかもしれません。まだ実現してない先のことを語っているのでしかたないのですが。

セカンドライフがネットで話題になるとき、こんなにしょぼい、すぐ落ちる、みたいな感じになりますが、ぼくもそう思います。現状の仮想世界はしょぼすぎる。でも未来もそうだとはおもいません。セカンドライフもメッシュインポートなど、様々な進歩をしています。

ネットの言説は、仮想世界がいつまでも進化しないとおもって書かれたものが多いです。未来にどうなっているのか、未来の仮想世界をどうしていくのか。そういった建設的な話をみてみたいです。